Working Hours Evidence Excel Workbook

As mentioned before, the code is used to cleanup the monthly calendar (and also to hide/unhide the days, of the month that exists). Another VBA macro is used to select the area and save its content to PDF file. This all, to allow signature of employee as well as employee's manager. The code uses Option Explicit method, so it is easier to recognize, if there is missing a definition of some variable used in the code. Please, find the code below:

Option Explicit

Sub Vymazat()
    Dim i As Long, PrvniRadka As Long, PosledniRadka As Long, ColNum As Long

    PrvniRadka = 6 'First day row
    PosledniRadka = 36 'Row of 31st day in month
    i = 0 'Reset of iteration variable value
    ColNum = 14 'Column number, where is hidden the formula calculating the week of year number - used for total hours in week calculation

    Worksheets("Evidence").Activate 'Select the Evidence sheet
    Worksheets("Evidence").Range("D6:K36").ClearContents 'Select and cleanup the range of A4 paper format
    For i = PrvniRadka To PosledniRadka '6 to 36 rows iteration
        If Cells(i, ColNum).Value <> 666 Then 'If there is a day in same month
            Cells(i, ColNum).EntireRow.Hidden = False 'do not hide the day
        Else 'for other rows in table, having the value 666 in N column
            Range("B" & i, "M" & i).Select 'select the row in table for further formatting - border
            Selection.Borders(xlDiagonalDown).LineStyle = xlNone 'horizontal bottom border row - not
            Selection.Borders(xlDiagonalUp).LineStyle = xlNone ' horizontal top border row - not
            Selection.Borders(xlEdgeLeft).LineStyle = xlNone 'left vertical border - not
            With Selection.Borders(xlEdgeTop) 'horizontal top border row - yes
                .LineStyle = xlContinuous 'solid
                .ThemeColor = 1 'color from the table template
                .TintAndShade = 0 'no shading of the color
                .Weight = xlThin 'thin border line
            End With
            With Selection.Borders(xlEdgeBottom) 'horizontal bottom border row - yes
                .LineStyle = xlContinuous 'solid
                .ThemeColor = 1 'color from the table template
                .TintAndShade = 0 'no color shading
                .Weight = xlThin 'thin border line
            End With
            Selection.Borders(xlEdgeRight).LineStyle = xlNone 'no right border
            With Selection.Borders(xlInsideVertical) 'setup of the vertical selection borders
                .LineStyle = xlContinuous 'solid
                .ThemeColor = 1 ' color from the table template
                .TintAndShade = 0 'no shading of the color
                .Weight = xlThin 'thin border line
            End With
            Selection.Borders(xlInsideHorizontal).LineStyle = xlNone 'no inner borders of selection
            Cells(i, ColNum).EntireRow.Hidden = True 'hide whole row
        End If
    Next i 'Next row
    ColNum = 1 'Column A
    For i = PrvniRadka To PosledniRadka 'iterace radkou od 6 do 36
        If Cells(i, ColNum).Value = "." Then 'pokud je ve sloupci A nalezena tecka
            Cells(i, ColNum + 3).Value = "State Holiday" 'tak ve sloupci D zvolit Statni Svatek
        End If
    Next i 'Dalsi radek
    Range("A1").Select 'Vyber bunky A1 po dokonceni behu makra
End Sub

Sub TiskDoPDF()
    Dim DochazkaRozsah As Range, PDFFile As String, pdffilename As String, Shex As Object, Cesta As String

    On Error GoTo ​DisplayError 'If Error occurrs display the error dialog
    Cesta = "" 'initialization of Path variable
    PDFFile = "" '​initialization of PDFFile variable
    Application.ScreenUpdating = False 'Display blinking of screens during switching between worksheets
    Cesta = Worksheets("Svátky").Range("E19").Value 'Autogenerated Path
    pdffilename = Application.WorksheetFunction.Text(Worksheets("Evidence").Range("Q8").Value & "/" & Worksheets("Evidence").Range("Q8").Value & "/" & Worksheets("Evidence").Range("Q6").Value, "yyyy-mm") & "-" & Application.WorksheetFunction.Substitute(Worksheets("Holidays").Range("$E2").Value, " ", "-") & ".pdf" 'resulting filename example: 2023-09-Michal-Kopl.pdf
    Worksheets("Evidence").Activate 'Selection of the worksheet for print
    Set DochazkaRozsah = Range("A1:N50") 'Range selection to printo into PDF file
    PDFFile = Cesta & pdffilename 'path and filename to store in PDF file
    DochazkaRozsah.ExportAsFixedFormat Type:=xlTypePDF, Filename:=PDFFile, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
    Set Shex = CreateObject("Shell.Application") 'Create the File System object
    Shex.Open (PDFFile) 'Open the created file in application to read the PDF file - eg. to add the signature
    Exit Sub 'Quit from the macro, so the error message below is not displayed

DisplayError:
    If Err.Number = -2147018887 Then 'It is not possible to write into the used file
        MsgBox "And here we have an error number: " & Err.Number & ", with meaning:" & vbCrLf & Err.Description & vbCrLf & "Any chance that the same file is opened in PDF file reader?", vbOKCancel, "Here we have an Error!!!"
    Else 'Other error
        MsgBox "​And here we have an error number: " & Err.Number & ", with menaning:" & vbCrLf & Err.Description, vbOKCancel, "Here we have an error!!!"
    End If
End Sub